Subcribe

A 10 minute tutorial for solving Math problems with Maxima

Posted by Antonio Cangiano in Essential Math, Software on June 4th, 2007 | 124 responses

About 50,000 people read my article 3 awesome free Math programs. Chances are that at least some of them downloaded and installed Maxima. If you are one of them but are not acquainted with CAS (Computer Algebra System) software, Maxima may appear very complicated and difficult to use, even for the resolution of simple high school or calculus problems. This doesn’t have to be the case though, whether you are looking for more math resources to use in your career or a student in an online bachelor’s degree in math looking for homework help, Maxima is very friendly and this 10 minute tutorial will get you started right away. Once you’ve got the first steps down, you can always look up the specific function that you need, or learn more from Maxima’s official manual. Alternatively, you can use the question mark followed by a string to obtain in-line documentation (e.g. ? integrate). This tutorial takes a practical approach, where simple examples are given to show you how to compute common tasks. Of course this is just the tip of the iceberg. Maxima is so much more than this, but scratching even just the surface should be enough to get you going. In the end you are only investing 10 minutes.

Maxima as a calculator

You can use Maxima as a fast and reliable calculator whose precision is arbitrary within the limits of your PC’s hardware. Maxima expects you to enter one or more commands and expressions separated by a semicolon character (;), just like you would do in many programming languages.

(%i1) 9+7;
(%o1) 16
(%i2) -17*19;
(%o2) -323
(%i3) 10/2;
(%o3) 5

Maxima allows you to refer to the latest result through the % character, and to any previous input or output by its respective prompted %i (input) or %o (output). For example:

(%i4) % - 10;
(%o4) -5
(%i5) %o1 * 3;
(%o5) 48

For the sake of simplicity, from now on we will omit the numbered input and output prompts produced by Maxima’s console, and indicate the output with a => sign. When the numerator and denominator are both integers, a reduced fraction or an integer value is returned. These can be evaluated in floating point by using the float function (or bfloat for big floating point numbers):

8/2;
=> 4
8/2.0;
=> 4.0
2/6;
=> \displaystyle \frac{1}{3}
float(1/3);
=> 0.33333333333333
1/3.0;
=> 0.33333333333333
26/4;
=> \displaystyle \frac{13}{2}
float(26/4);
=> 6.5

As mentioned above, big numbers are not an issue:

13^26;
=> 91733330193268616658399616009
13.0^26
=> \displaystyle 9.1733330193268623\text{ }10^_{+28}
30!;
=> 265252859812191058636308480000000
float((7/3)^35);
=> \displaystyle 7.5715969098311943\text{ }10^_{+12}

Constants and common functions

Here is a list of common constants in Maxima, which you should be aware of:

  • %e – Euler’s Number
  • %pi – \displaystyle \pi
  • %phi – the golden mean (\displaystyle \frac{1+\sqrt{5}}{2})
  • %i – the imaginary unit (\displaystyle \sqrt{-1})
  • inf – real positive infinity (\infty)
  • minf – real minus infinity (-\infty)
  • infinity – complex infinity

We can use some of these along with common functions:

sin(%pi/2) + cos(%pi/3);
=> \displaystyle \frac{3}{2}
tan(%pi/3) * cot(%pi/3);
=> 1
float(sec(%pi/3) + csc(%pi/3));
=> 3.154700538379252
sqrt(81);
=> 9
log(%e);
=> 1

Defining functions and variables

Variables can be assigned through a colon ‘:’ and functions through ‘:=’. The following code shows how to use them:

a:7; b:8;
=> 7
=> 8
sqrt(a^2+b^2);
=> \sqrt{113}
f(x):= x^2 -x + 1;
=> x^2 -x + 1
f(3);
=> 7
f(a);
=> 43
f(b);
=> 57

Please note that Maxima only offers the natural logarithm function log. log10 is not available by default but you can define it yourself as shown below:

log10(x):= log(x)/log(10);
=> \displaystyle log10(x):=\frac{log(x)}{log(10)};
log10(10)
=> 1

Symbolic Calculations

factor enables us to find the prime factorization of a number:

factor(30!);
=> \displaystyle 2^{26}\,3^{14}\,5^7\,7^4\,11^2\,13^2\,17\,19\,23\,29

We can also factor polynomials:

factor(x^2 + x -6);
=> (x-2)(x+3)

And expand them:

expand((x+3)^4);
=> \displaystyle x^4+12\,x^3+54\,x^2+108\,x+81

Simplify rational expressions:

ratsimp((x^2-1)/(x+1));
=> x-1

And simplify trigonometric expressions:

trigsimp(2*cos(x)^2 + sin(x)^2);
=> \displaystyle \cos ^2x+1

Similarly, we can expand trigonometric expressions:

trigexpand(sin(2*x)+cos(2*x));
=> \displaystyle -\sin ^2x+2\,\cos x\,\sin x+\cos ^2x

Please note that Maxima won’t accept 2x as a product, it requires you to explicitly specify 2*x. If you wish to obtain the TeX representation of a given expression, you can use the tex function:

tex(%);
=> $$-\sin ^2x+2\,\cos x\,\sin x+\cos ^2x$$

Solving Equations and Systems

We can easily solve equations and systems of equations through the function solve:

solve(x^2-4,x);
=> \displaystyle \left[ x=-2 , x=2 \right]
%[2]
=> x=2
solve(x^3=1,x);
=> \displaystyle \left[ x={{\sqrt{3}\,i-1}\over{2}} , x=-{{\sqrt{3}\,i+1}\over{2}}  , x=1 \right]
trigsimp(solve([cos(x)^2-x=2-sin(x)^2], [x]));
=> \displaystyle \left[ x=-1 \right]
solve([x - 2*y = 14,  x + 3*y = 9],[x,y]);
=> \left[ \left[ x=12 , y=-1 \right]  \right]

2D and 3D Plotting

Maxima enables us to plot 2D and 3D graphics, and even multiple functions in the same chart. The functions plot2d and plot3d are quite straightforward as you can see below. The second (and in the case of plot3d, the third) parameter, is just the range of values for x (and y) that define what portion of the chart gets plotted.

plot2d(x^2-x+3,[x,-10,10]);

2dplot.png

plot2d([x^2, x^3, x^4 -x +1] ,[x,-10,10]);

many_2dplot.png

f(x,y):= sin(x) + cos(y);
plot3d(f(x,y), [x,-5,5], [y,-5,5]);

3dplot.png

Limits

limit((1+1/x)^x,x,inf);
=> %e
limit(sin(x)/x,x,0);
=> 1
limit(2*(x^2-4)/(x-2),x,2);
=> 8
limit(log(x),x,0,plus);
=> -\infty
limit(sqrt(-x)/x,x,0,minus);
=> -\infty

Differentiation

diff(sin(x), x);
=> \displaystyle cos(x)
diff(x^x, x);
=> \displaystyle x^{x}\,\left(\log x+1\right)

We can calculate higher order derivatives by passing the order as an optional number to the diff function:

diff(tan(x), x, 4);
=> \displaystyle 8\,\sec ^2x\,\tan ^3x+16\,\sec ^4x\,\tan x

Integration

Maxima offers several types of integration. To symbolically solve indefinite integrals use integrate:

integrate(1/x, x);
=> \displaystyle log(x)

For definite integration, just specify the limits of integrations as the two last parameters:

integrate(x+2/(x -3), x, 0,1);
=> \displaystyle -2\,\log 3+2\,\log 2+{{1}\over{2}}
integrate(%e^(-x^2),x,minf,inf);
=> \sqrt{\% pi}

If the function integrate is unable to calculate an integral, you can do a numerical approximation through one of the methods available (e.g. romberg):

romberg(cos(sin(x+1)), x, 0, 1);
=> 0.57591750059682

Sums and Products

sum and product are two functions for summation and product calculation. The simpsum option simplifies the sum whenever possible. Notice how the product can be use to define your own version of the factorial function as well.

sum(k, k, 1, n);
=> \displaystyle \sum_{k=1}^{n}{k}
sum(k, k, 1, n), simpsum;
=> \displaystyle {{n^2+n}\over{2}}
sum(1/k^4, k, 1, inf), simpsum;
=> \displaystyle {{\%pi^{4}}\over{90}}
fact(n):=product(k, k, 1, n);
=> fact(n):=product(k,k,1,n)
fact(10);
=>  3628800

Series Expansions

Series expansions can be calculated through the taylor method (the last parameter specifies the depth), or through the method powerseries:

niceindices(powerseries(%e^x, x, 0));
=> \displaystyle \sum_{i=0}^{\infty }{{{x^{i}}\over{i!}}}
taylor(%e^x, x, 0, 5);
=> \displaystyle 1+x+{{x^2}\over{2}}+{{x^3}\over{6}}+{{x^4}\over{24}}+{{x^5}\over{120 }}+\cdots

The trunc method along with plot2d is used when taylor’s output needs to be plotted (to deal with the +\cdots in taylor’s output):

plot2d([trunc(%), %e^x], [x,-5,5]);

taylor.png

I hope you’ll find this useful and that it will help you get started with Maxima. CAS can be powerful tools and if you are willing to learn how to use them properly, you will soon discover that it was time well invested.

Sponsor’s message: Math Better Explained is an insightful ebook and screencast series that will help you deeply understand fundamental mathematical concepts, and see math in a new light. Get it here.

Possibly related articles:

  1. 3 awesome free Math programs
  2. What kind of Math did they teach you?
  3. Refresh your High School Math skills

If you enjoyed this post, then make sure you subscribe
to our Newsletter and/or RSS Feed.


124 Responses to “A 10 minute tutorial for solving Math problems with Maxima”

  1. Alex says:
    September 11, 2009 at 10:14 am

    Hi
    I’m alex..I write because I knew Maxima last year and using there in linux, it’s amazing!!!..But now I want install Maxima in WinXP (for work) and I fail the configuration because there is a problem with a socket!!!
    How Can I do?
    thanks (Sorry for my English)!!!
    Bie!!!

    Reply
  2. Hank says:
    September 20, 2009 at 1:08 am

    Hi –

    Don’t forget to check out the best Maxima tutorial IMHO:

    http://www.csulb.edu/~woollett/

    Cheers!

    Reply
  3. Larry Dickson says:
    September 25, 2009 at 2:06 pm

    How do you gracefully exit the maxima program? exit; and quit; don’t work. I tried ? quit and did get out via a stack overflow :-) but surely there is some way out other than crashing???

    Reply
  4. Antonio Cangiano says:
    September 25, 2009 at 2:28 pm

    Larry, quit(); will exit maxima. :)

    Reply
  5. Alexandros says:
    September 26, 2009 at 6:06 am

    I exit maxima with Ctrl-D.

    Reply
  6. samuel measho says:
    October 14, 2009 at 3:07 pm

    HI ,I just want to ask how can i use maxima to compute and draw the graph of complex numbers.

    Reply
  7. David Friedman says:
    October 16, 2009 at 4:22 pm

    I’m trying Maxima now, after closing my sage session. I ran into trouble using sage to define a symbolic sum e.g. you want to define a function like:

    f(x) = sum(i, i, 1, x);

    apparently sage cannot do that at this point in the development. It was disappointing that sage couldn’t do this (or if it is possible to do this I couldn’t figure it out after an hour of trying).

    sage is actually the first hit after a google search for “sage”, so it is still popular, and maybe it’ll improve by leaps and bounds, but at least after the first ten minutes I have a better feeling about Maxima.

    when I was searching for a way to solve my problem I found this thread, which indicates
    that this functionality is on the way for the sage:

    http://groups.google.com/group/sage-support/browse_thread/thread/cf9cb4e92ce3bc04/f5e41d8aa31294e4?lnk=gst&q=sum#f5e41d8aa31294e4

    it seems to me that sage is more of an interface to or a concatenation of a lot of other programs (latex, r, maxima, python etc., and also commercial programs like mathematica, matlab). I guess one has to ask whether when doing a task it is better to use sage as a single command center, or to just use that program directly.

    Reply
  8. Rob says:
    November 14, 2009 at 6:31 pm

    When I try your example:

    trigsimp(2*cos(x)^2 + sin(x)^2);

    I get
    => \displaystyle \cos(x)^2+1
    instead of
    => \displaystyle \cos ^2x+1

    Reply
    • jerzy says:
      March 10, 2012 at 3:44 pm

      Maxima gives correct result, because:
      2*cos(x)^2 + sin(x)^2=
      cos(x)^2+cos(x)^2 + sin(x)^2=
      cos(x)^2+1

      where
      cos(x)^2 + sin(x)^2=1

      Reply
  9. Ivan Belash says:
    December 16, 2009 at 4:20 am

    You forget one, but very important thing: how to run – Ctrl+R
    It really easy, but it was a problem for me.

    Reply
  10. AKE says:
    February 22, 2010 at 2:41 pm

    Very nice tutorial introduction! Highly recommended first intro to Maxima.

    I’ve put together a selection of the Maxima resources that I’ve found most useful over the years, including a succinct instruction cheatsheet, a guide to programming subroutines/scripts, and a Mathematica-Maxima syntax conversion chart.

    They’re available here:
    http://mathscitech.org/articles/maxima

    Enjoy!

    Reply
  11. A Rubens de Castro says:
    March 24, 2010 at 6:47 am

    I am using wxMaxima on Ubuntu9.10.
    I understand that wxMaxima is just a front-end, the Maxima Kernel does not exist in my computer, it resides somewhere else.
    All the examples you give are very easy, however
    I have a problem not covered on your tutorial: after a given number of operations (computations, writes to disk, etc) my connection with Maxima is terminated, it is like a time-out. Then I have to click on “Restart Maxima” to go on with my calculations for some other value of the parameters.
    Anything obvious which I should but am not doing ??? My colleagues say Maxima works better than Mathematica !

    A Rubens

    Reply
  12. Alexander says:
    April 23, 2010 at 12:19 pm

    I am recently retired and cut my math curious teeth with “Mathematica for students” circa fall 2000. The past ten years i have developed computer parametric geometry to explor gravity curves and have a written manuscript that would work best with a “symbolic logic program” such as Derive or Mathematica in the back cover. TI did’t want to look at it (Derive had more then enough power to study simple curvature relations) and Mathematica never replied. I know it would push education of math beyond expectations simply because I had so much fun doing it. Can any one out there help get this project “air borne”. Not in “education” I had no idea Maxima or others existed and there is little difference betwixt utility gained! Thanks for the tutorial and I will attempt the download and application.

    Reply
  13. Ricardo M says:
    August 24, 2011 at 5:27 pm

    Men necesito un gran favor! necesito saber si sabes resolver problemas de optimizacion lineal con este programa, se lo agradeceria mucho!

    Reply
  14. synhedionn says:
    September 6, 2011 at 6:49 am

    Hi,
    In Maxima: sum(i,i,1,n); gives sum(i,i,1,n);
    Can’t it give n(n+1)/2?

    Reply
  15. Ragbir Chana says:
    November 11, 2011 at 9:39 am

    Great tutorial. I like tutorials doing by example.

    Reply
  16. Derek Pilous says:
    March 5, 2012 at 5:52 pm

    Fantastic tutorial, thank you very much. If you’re not a teacher, you should be (well, if you’re scientist, you’re excused ;) ). I am teacher myself and I can say, there are few people capable of writing so comprehensible and yet inspiring introduction to topic. Sorry for my English :)

    Reply
  17. jerzy says:
    March 10, 2012 at 3:53 pm

    Clear, simple, useffull, beautiful work. Thanks.

    Reply
  18. RockyRoad says:
    April 3, 2012 at 6:31 am

    Great work Antonio, thank you very much :)

    Inspiring ? Yes !

    I’m nearly new to CAS programs (played a bit with gnuplot though), my last math classes are over 25 years old now … not easy !

    I’m delighted to discover what Maxima can do for me and feel eager to refresh and
    and expand my math notions and practice.

    Your tutorial could do that !

    Reply
  19. M Kanagasabapathy says:
    May 6, 2012 at 1:57 am

    Dear Antonio Cangiano,

    Excellent and Nice tutorial. Kindly proceed for higher computations , tensors, numerical simulations etc., if possible. It can be beneficial for researchers and students.
    Dr M Kanagasabapathy

    Reply
  20. phobos says:
    May 8, 2012 at 7:07 am

    How to use if condition inside for loop.
    I am using the following:

    new:makelist(0);
    k:1;
    for i from 1 thru 10 do (
    (if(imagpart(xvals[i]) = 0) then ab:makelist(xvals[i]),new:append(new,ab),k:k+1)
    );

    But, the if condition also gets executed 10 times.. though clearly it is not the case in my program.

    Reply
  21. KSO says:
    May 8, 2012 at 8:38 pm

    I’m trying to add random noise to a function, but the random() function only generates a single number, giving me an offset. I want my function to plot a Lorentzian curve, for example, but I want random white noise added to every point, not just one. I used the following function definition:

    Lno(G,x0,x):=(
    r:random(x),
    1/%pi*(0.5*G)/((x-x0)^2+(0.5*G)^2)+r
    );

    and tried another

    Lnoi(G,x0,x):=1/%pi*(0.5*G)/((x-x0)^2+(0.5*G)^2)+random(1.2);

    All I get is a smooth Lorentzian curve with a random offset when I plot using plot2d, not random noise at every point.

    Does anyone know how to do this?

    Reply
« Older Comments

Leave a Reply